;------------------------------------------------------
; TEST DELLA RAM
;
; Per monitor multi-firmware
; Allocato a F000h nella eprom
;------------------------------------------------------

	.include	"jump.inc"

; Indirizzi working area
stack	.equ	000efh			; indirizzo inziale dello stack pointer
rampda	.equ	000f0h			; ram presente - E' quella che viene controllata affinché non cambi
rampa	.equ	000f2h
ramtda	.equ	000f4h			; ram da testare
ramta	.equ	000f6h
cursv	.equ	000f8h			; posizione del cursore (non del carattere) sul video vecchio
cursn	.equ	000fah			; posizione del cursore sul video nuovo
cursd	.equ	000fch			; posizione del cursore sui display
curfon	.equ	000fdh			; flag cursori accesi. Se =00h i cursori sono accesi, se =20h i cursori sono spenti
tiptes	.equ	000feh			; tipo di test richiesto. 01h=base, 02h=avanzato

	.org	0F000h

; JUMP table
	jp	inizio			; F000h inizio programma
	jp	vis			; F003h visualizza il messaggio puntato da HL sui vi
	jp	inp			; F006h input in HL del numero di caratteri esadecimali indicati dal registro D
	
inizio:	ld	hl,45EDh   		; disabilita i tasti BREAK
	ld	(0066h),hl
	
	ld	hl,0000h		; controlla se la ram da 0000h a 00FFh è OK

lopram:	xor	a			; controlla la cella per 00h
	ld	(hl),a
	ld	a,(hl)
	or	a			; cp 00h
	jp	nz,errram		; se c'è un errore esce
	
	cpl				; controlla la cella per 0ffh
	ld	(hl),a
	ld	a,(hl)
	cp	0ffh
	jp	nz,errram		; se c'è un errore esce

	and	01010101b		; controlla la cella per 01010101b
	ld	(hl),a
	ld	a,(hl)
	cp	01010101b
	jp	nz,errram		; se c'è un errore esce

	cpl				; controlla la cella per 10101010b
	ld	(hl),a
	ld	a,(hl)
	cp	10101010b
	jp	nz,errram		; se c'è un errore esce
	
	inc	hl			; salta alla cella successiva
	ld	a,h			; esce a 0100h
	cp	01h
	jr	nz,lopram

;------------------------------------------------------

	ld	hl,stack		; imposta lo stack pointer
	ld	sp,hl		

	call	lf0a5			; inizializza i registri del SY6545 ed i PIO della scheda video nuova
	call	checv			; imposta il registro B' che indica se esiste la scheda video vecchia
	
	ld	a,01h			; imposta il registro D', che indica che l'input da tastiera deve controllare anche il BACKSPACE
	exx
	ld	d,a
	exx

	ld	a,0C3h   		; abilita i tasti BREAK
	ld	(0066h),a
	ld	hl,break
	ld	(0067h),hl

	call	inivid			; inizializza la schermata video
        
        ld	hl,msg1			; visualizza "TEST RAM"
        ld	de,tabds1		; visualizza il menù sui display
        call	vis
        
        ld	hl,help			; visualizza l'help
        call	vis
        
        ld	hl,menu			; visualizza il menù
        call	vis
	
linp1:	call	curon			; accende il cursore
	call	input			; input di un carattere
	call	curoff			; spegne il cursore        
        
        ld	(tiptes),a		; salva il tipo di test richiesto
        
        cp	03h			; se è stato digitato 3 -> fine programma
        jr	nz,linp1x
        jp	0f800h
        
linp1x:	cp	01h			; controlla che sia stato digitato solo 1 o 2
        jr	z,linp1a
        
        cp	02h
        jr	z,linp1a
        
        jr	linp1

;------------------------------------------------------
        
linp1a:	call	inivid			; inizializza la schermata video

        ld	a,(tiptes)
        cp	02h
        jr	z,linp1b
        
        ld	hl,msg15		; visualizza "TEST RAM SEMPLICE"
        jr	linp1c
        
linp1b:	ld	hl,msg16		; visualizza "TEST RAM AVANZATO"
linp1c:	ld	de,tabds2		; visualizza sui display
	call	vis

	ld	hl,msg2			; visualizza "RAM DA TESTARE: "
        call	vis
        
linp2:	ld	hl,msg3			; visualizza "INDIRIZZO INIZIALE: "
	ld	de,tabds2		; visualizza sui display
	call	indir			; visualizzazione messaggio, input dell'indirizzo e controllo che non sia < 0100h
	jr	nz,linp2
	ld	(ramtda),hl		; salva l'indirizzo iniziale
        
linp3:	ld	hl,msg4			; visualizza "INDIRIZZO FINALE: "
	ld	de,tabds3		; visualizza sui display
	call	indir			; visualizzazione messaggio, input dell'indirizzo e controllo che non sia < 0100h
	jr	nz,linp3
	ld	(ramta),hl		; salva l'indirizzo finale
        
        or	a			; azzera il carry
        ld	bc,(ramtda)		; se l'indirizzo finale è <= di iniziale richiede gli indirizzi
        sbc	hl,bc
        jr	c,linp4
        jr	z,linp4
        jr	linp5			; altrimenti prosegue
        
linp4:	ld	hl,msg14		; visualizza messaggio di errore
	ld	de,0000h
        call	vis
        
	ld	hl,msg3			; cancella le righe di input alla posizione di msg3 e msg4
        call	delinp
        ld	hl,msg4
        call	delinp
        jr	linp2

;------------------------------------------------------

linp5:	ld	a,(tiptes)		; verifica il tipo di test richiesto
	cp	01h
	jr	z,linp9			; se 01h evita il test avanzato

	ld	hl,msg5			; visualizza "RAM CHE NON SI DEVE MODIFICARE: "
	ld	de,tabds4
        call	vis
        
linp6:	ld	hl,msg6			; visualizza "INDIRIZZO INIZIALE: "
	call	indir			; visualizzazione messaggio, input dell'indirizzo e controllo che non sia < 0100h
	jr	nz,linp6
	ld	(rampda),hl		; salva l'indirizzo iniziale
        
linp7:	ld	hl,msg7			; visualizza "INDIRIZZO FINALE: "
	ld	de,tabds5		; visualizza sui display
	call	indir			; visualizzazione messaggio, input dell'indirizzo e controllo che non sia < 0100h
	jr	nz,linp7
	ld	(rampa),hl		; salva l'indirizzo finale
        
        or	a			; azzera il carry
        ld	bc,(rampda)		; se l'indirizzo finale è <= di iniziale richiede gli indirizzi
        sbc	hl,bc
        jr	c,linp8
        jr	z,linp8
        jr	linp9			; altrimenti prosegue
        
linp8:	ld	hl,msg14		; visualizza messaggio di errore
	ld	de,0000h
        call	vis
        
        ld	hl,msg6			; cancella le righe di input alla posizione di msg6 e msg7
        call	delinp
        ld	hl,msg7
        call	delinp
        jr	linp6

;------------------------------------------------------
        
linp9:	ld	hl,tabds6		; visualizza sui display
	call	vdisp
	
	ld	hl,msg8			; visualizza "ATTENDERE..."
	ld	de,0000h
	call	vis
	
	ld	a,(tiptes)		; se il test è semplice non serve azzerare la ram
	cp	01h			; perchè non bisogna verificare se si modifica da sola
	jr	z,linp10
	
	or	a			; azzera il carry
	ld	hl,(rampa)		; azzera tutta la ram presente
	ld	bc,(rampda)
	sbc	hl,bc
	push	hl

	pop	bc
	ld	hl,(rampda)		
	ld	de,(rampda)
	inc	de
	xor	a                                                             
	ld	(hl),a
	ldir

linp10:	ld	hl,(ramtda)		; carica l'indirizzo iniziale da testare

;------------------------------------------------------

loop:	push	hl			; posiziona il cursore per visualizzare l'indirizzo in fase di test
	ld	hl,adr1
	call	poscur
	pop	hl

	ld	a,0f3h			; posiziona il cursore per i display
	ld	(cursd),a
		
	call	visadr			; visualizza l'indirizzo in fase di test

	xor	a			; controlla la cella per 00h
	ld	(hl),a
	ld	a,(hl)
	or	a			; cp 00h
	jr	nz,err

	cpl				; controlla la cella per 0ffh
	ld	(hl),a
	ld	a,(hl)
	cp	0ffh
	jr	nz,err
	
	and	01010101b		; controlla la cella per 01010101b
	ld	(hl),a
	ld	a,(hl)
	cp	01010101b
	jp	nz,err			; se c'è un errore esce

	cpl				; controlla la cella per 10101010b
	ld	(hl),a
	ld	a,(hl)
	cp	10101010b
	jp	nz,err			; se c'è un errore esce

	xor	a			; azzera la locazione scritta
	ld	(hl),a

	ld	a,(tiptes)		; se il test è avanzato controlla che la ram non si sia modificata
	cp	02h
	call	z,chkram

	inc	hl			; salta alla cella successiva
	
	ld	a,h			; controlla se HL=0000h. Se sì significa che ha passato 0fffh, quindi esce
	or	l
	jr	z,fine
	
loop1:	ld	de,(ramta)		; controlla se ha finito. Esce all'indirizzo "ramta"+1
	or	a			; azzera il carry
	push	hl
	sbc	hl,de			; imposta il carry se hl<de
	pop	hl
	jr	c,loop
	jr	z,loop

ok:	ld	hl,msg9			; visualizza "RAM OK"
	ld	de,tabds9		; visualizza sui display
	call	vis
	
	jr	fine

err:	push	hl
	ld	hl,msg10		; visualizza "ERRORE: "
	ld	de,tabds7		; visualizza sui display
	call	vis
	pop	hl
	
	ld	a,0f3h			; posiziona il cursore per i display
	ld	(cursd),a

	call	visadr			; visualizza l'indirizzo in errore

fine:	ld	hl,msg12		; visualizza "FINE PROGRAMMA" e "PREMERE BREAK PER RIPETERE"
	ld	de,0000h
	call	vis

	halt

;------------------------------------------------------

errram:	ld	hl,disper		; visualizza l'errore "Err. Pag.0" sui display
	ld	c,0f8h
	ld	b,08h
errra1:	dec	c
	outi
	jr	nz,errra1

	ld      hl,0ec00h		; azzera il video vecchio
        ld      de,0ec01h
        ld      (hl),20h
        ld      bc,01ffh
        ldir
        
        ld	hl,errpag		; visualizza l'errore "ERRORE RAM IN PAGINA 0" sul video vecchio
        ld	de,0ec00h
errra2:	ldi
        ld	a,(hl)
        or	a			; cp 00h
        jr	nz,errra2

errra3:	xor	a			; fa un beep sulla scheda video nuova
	out	(8fh),a
	
	ld	hl,4000h		; fa un ritardo
errra4:	dec	hl
	ld	a,h
	or	l
	jr	nz,errra4
	jr	errra3			; looppa facendo un altro beep
	
;------------------------------------------------------
; Controlla che la ram non sia cambiata
;

chkram:	push	bc			; controlla se tutta la ram ad eccezione dell'indirizzo puntato da HL è a 00h
	push	hl
	ld	hl,(rampda)
	ld	bc,(rampa)

	dec	hl	

check1:	inc	hl
	xor	a
	cp	(hl)
	jr	nz,chkerr		; se nella locazione non c'è 00h è un errore della ram, altrimenti controlla se ha finito
	
	ld	a,l			; se HL=BC allora ha finito, altrimenti looppa
	xor	c
	jr	nz,check1
	ld	a,h
	xor	b
	jr	nz,check1
	
	pop	hl			; ripristina i registri e ritorna
	pop	bc
	ret

chkerr:	push	hl			; visualizza "ERRORE - BYTE CAMBIATO..."
	ld	hl,msg11
	call	vis
	
	ld	hl,tabds8		; visualizza sui display
	call	vdisp
	pop	hl
	
	ld	a,0f3h			; posiziona il cursore per i display
	ld	(cursd),a

	call	visadr			; visualizza l'indirizzo in errore
	
	pop	hl
	pop	bc
	
	inc	sp			; incrementa lo stack pointer per via dell'uscita tramite jump (e non tramite ret)
	inc	sp
	jp	fine

;------------------------------------------------------
; Input di un indirizzo con controllo se è < 0100h
; Ritorna l'indirizzo in HL, e flag NZ se minore di 0100h

indir:  push	bc
	push	de
	
	call	vis			; visualizza il messaggio puntato da HL a video, e puntato da DE sui display
	
	ld	a,0f3h			; imposta la posizione sui display
	ld	(cursd),a
	
        ld	d,04h			; numero di caratteri in input
        call	inp			; input dell'indirizzo in HL
	push	hl

	ld	bc,0100h		; controlla se HL<0100h
	or	a			; azzera il carry
	sbc	hl,bc			; se HL<BC imposta il carry
        
        jr	c,indi1			; se HL<0100h tratta l'errore
        xor	a			; imposta Z
        jr	indi2
        
indi1:	ld	b,04h			; se <0100h lo cancella e imposta NZ
        call	deladr
        ld	hl,msg13		; visualizza errore indirizzo<0100h
        ld	de,0000h
        call	vis
        or	0ffh			; imposta NZ

indi2:	pop	hl
	pop	de
        pop	bc
        ret

;------------------------------------------------------
; Subroutine per l'input e la visualizzazione del numero di cifre esadecimali indicate dal registro D
; "cursv" deve contenere l'indirizzo del video vecchio. Il video nuovo deve essere già posizionato
; Ritorna il valore digitato in HL
;

inp:	push	af
	push	bc
	push	de
	
inp1a:	ld	hl,0000h		; inizializza il valore di ritorno
	ld	b,00h			; numero di caratteri inseriti
	
inp1:	call	curon			; accende il cursore
	call	input			; input di un carattere
	call	curoff			; spegne il cursore

	call	clrmsg			; cancella l'eventuale messaggio di errore
	
	cp	010h			; se viene premuto RETURN lo gestisce
	jr	z,inp3
	
	cp	01fh			; Se viene premuto BACKSPACE cancella l'indirizzo
	jr	nz,inp2			; altrimenti prosegue

	call	deladr
	jr	inp1a
	
inp2:	ld	c,a			; salva il registro A
	ld	a,b			; controlla se sono stati digitati il numero di caratteri richiesto 
	cp	d
	jr	z,inp1			; se sì non ne accetta altri
	
	ld	a,c			; recupera il registro A
	call	mem			; memorizza il byte digitato in HL
	call	dispca			; visualizza il carattere premuto a video e sui display

	inc	b
	jr	inp1

mem:	push	af			; memorizza il byte digitato (1 byte) in HL
	push	af
	sla	h
	sla	h
	sla	h
	sla	h
	ld	a,l
	call	srla4
	or	h
	ld	h,a
	sla	l
	sla	l
	sla	l
	sla	l
	pop	af
	and	0fh
	or	l
	ld	l,a
	pop	af
	ret

inp3:	push	hl			; cancella l'indirizzo digitato (che può avere meno di 4 caratteri) e lo visualizza intero
	call	deladr

	ld	b,d			; numero di caratteri da visualizzare + 1
	inc	b
	
	push	hl
inp4:	ld	hl,(cursv)		; sposta il cursore verso destra del numero di caratteri da visualizzare + 1, perché la visualizzazione avviene al contrario (da destra a sinistra)
	inc	hl
	ld	(cursv),hl
	ld	hl,(cursn)
	inc	hl
	ld	(cursn),hl
	djnz	inp4
	pop	hl
	
	ld	b,d			; numero di caratteri da visualizzare
inp5:	push	hl
	ld	hl,(cursv)		; posiziona il cursore prima dell'ultimo carattere visualizzato
	dec	hl			; ultimo carattere
	dec	hl			; penultimo carattere
	ld	(cursv),hl
	ld	hl,(cursn)
	dec	hl
	dec	hl
	ld	(cursn),hl
	pop	hl

	ld	a,l			; visualizza il carattere premuto a video. Sui display non viene visualizzato perché viene cancellato subito
	and	0fh
	call	dispch
	
	ld	a,l			; ruota a destra HL
	call	srla4
	and	0fh
	ld	l,a
	
	ld	a,h
	rla
	rla
	rla
	rla
	and	0f0h
	or	l
	ld	l,a
	
	ld	a,h
	call	srla4
	and	0fh
	ld	h,a
	
	djnz	inp5			; looppa
	
	ld	c,d			; posiziona il cursore dopo i caratteri visualizzati
	ld	b,00h
	ld	hl,(cursv)
	add	hl,bc
	dec	hl
	ld	(cursv),hl
	ld	hl,(cursn)
	add	hl,bc
	dec	hl
	ld	(cursn),hl

	pop	hl
	pop	de
	pop	bc
	pop	af
	ret

;------------------------------------------------------
; visualizza il carattere a video s sui display
;

dispca:	call	dispch			; visualizza il carattere premuto
	call	posdis			; posiziona in C il display da utilizzare e incrementa la posizione del cursore dei display
	call	vdispc			; visualizza il carattere sui display
	
	ret
	
;------------------------------------------------------
; Cancella l'indirizzo digitato
; Il registro B contiene il numero di caratteri da cancellare
;

deladr:	push	af
	push	bc
	push	hl
	
delad1:	ld	a,b			; se non ci sono più caratteri da cancellare esce
	or	a			; cp 00h
	jp	z,delad2
	
	ld	hl,(cursv)		; decrementa la posizione del cursore del video vecchio
	dec	hl
	ld	(cursv),hl
	
	ld	hl,(cursn)		; decrementa la posizione del cursore del video nuovo
	dec	hl
	ld	(cursn),hl
	call	lf060			; riposiziona il cursore sul video nuovo
	
	ld	a,(cursd)		; incrementa la posizione del cursore dei display
	inc	a
	ld	(cursd),a
	
	ld	a,20h			; scrive un blank
	call	disp
	
	ld	a,011h			; carattere "blank" per i display secondo TABDIS
	call	posdis			; posiziona in C il display da utilizzare e incrementa la posizione del cursore dei display
	call	vdispc

	ld	hl,(cursv)		; decrementa la posizione del cursore del video vecchio
	dec	hl
	ld	(cursv),hl
	
	ld	hl,(cursn)		; decrementa la posizione del cursore del video nuovo
	dec	hl
	ld	(cursn),hl
	call	lf060			; riposiziona il cursore sul video nuovo

	ld	a,(cursd)		; incrementa la posizione del cursore dei display
	inc	a
	ld	(cursd),a
	
	dec	b			; decrementa il numero di caratteri da cancellare
	jr	delad1

delad2:	pop	hl
	pop	bc
	pop	af
	ret

;------------------------------------------------------
; Cancella due righe di input alla posizione del messaggio indicato da HL
;

delinp:	push	hl
	
	call	poscur			; posiziona il cursore in base alla riga/colonna puntata da HL e HL+1
	
	ld	hl,msg0+2		; punta al messaggio da visualizzare (riga con blank)
	call	vis1			; visualizza il messaggio senza posizionare il cursore
	
	pop	hl
	ret

;------------------------------------------------------
; Subroutine per la visualizzazione della riga di messaggio a video e sui display
; HL deve contenere il primo carattere da visualizzare a video
; DE deve contenere il primo carattere da visualizzare sui display
; Ritorna la posizione del video vecchio in "cursv", del video nuovo in "cursn"
; Il video nuovo avrà il cursore posizionato automaticamente
; Con l'entry-point "vis1" il cursore deve essere già posizionato

vis:	push	af
	call	poscur			; calcola e posiziona il cursore alla riga/colonna indicata dalla locazione di memoria puntata da HL e HL+1
	pop	af
	
vis1:	push	af
vis2:	ld	a,(hl)			; recupera il carattere da scrivere
	call	disp			; visualizza il carattere
	
	inc     hl
        xor	a			; controlla se il prossimo carattere è 00h
        cp      (hl)
	jr	z,vis3			; se è 00h esce
	
	inc	a			; se non è 01h visualizza il carattere
	cp	(hl)
	jr	nz,vis2
	
	inc	hl			; altrimenti torna a posizionare il cursore e visualizzare il messaggio
	pop	af
	jr	vis

vis3:	ld	a,d			; se DE è 0000h non visualizza il messaggio sui display
	or	e
	jr	z,vis4
	
	ex	de,hl			; visualizza il messaggio sui display
	call	vdisp
	ex	de,hl
	
vis4:	pop	af
	ret

;------------------------------------------------------
; Posiziona il cursore in base alla riga/colonna indicata dalla locazione puntata da HL
; Ritorna la posizione del video vecchio in "cursv", del video nuovo in "cursn"
; Alla fine HL conterrà il primo carattere da visualizzare
;

poscur:	push	af
	push	de
	push	hl
	
	call	nloc			; calcola la posizione dell'indirizzo da visualizzare sul video nuovo in base alla riga/colonna puntata da HL e HL+1
	ld	(cursn),de		; salva la posizione del cursore del video nuovo
	push	de			; copia la posizione in HL
	pop	hl
	call	lf060			; posiziona il cursore sul video nuovo
	
	pop	hl			; calcola la posizione dell'indirizzo da visualizzare sul video vecchio in base alla riga/colonna puntata da HL e HL+1
	call	vloc
	ld	(cursv),de		; salva la posizione del cursore del video vecchio
	
	pop	de
	pop	af
	ret

;------------------------------------------------------
; Subroutine per la visualizzazione di un carattere a video
; "cursv" contiene l'indirizzo del video vecchio. Al termine "cursv" e "cursn" contengono l'indirizzo successivo
; "dispch" effettua la conversione del numero/lettera in carattere ascii
; "disp" non effettua la conversione
;

disp:	push	af
	jr	disp2
	
dispch:	push	af			; visualizza il carattere digitato
	cp	0ah
	jr	nc,disp1		; se A >= 0ah addiziona 037h, altrimenti 030h

	add	a,030h
	jr	disp2

disp1:	add	a,037h

disp2:	push	hl

	ld	hl,(cursv)		; legge l'indirizzo attuale del cursore
	call	waitv			; attende la ritraccia del video vecchio
	ld	(hl),a			; visualizza il carattere sul video vecchio
	inc	hl
	ld	(cursv),hl		; salva il nuovo indirizzo del cursore del video vecchio
	
disp2a:	push	af
	ld	a,(curfon)		; se il cursore sul video vecchio era acceso lo visualizza
	or	a
	jr	nz,disp3
	
	ld	a,81h			; accende (scrive) il cursore sul video vecchio
	ld	(hl),a
	
disp3:	ld	hl,(cursn)		; posiziona il carattere da visualizzare sul video nuovo
	call	lf06e
	
	pop	af
	call	writen			; attende la ritraccia e visualizza il carattere sul video nuovo

	ld	hl,(cursn)		; salva la nuova posizione del cursore del video nuovo
	inc	hl
	ld	(cursn),hl
	
	call	lf060			; posiziona il cursore sul video nuovo

	ld	a,(curfon)		; accende o spegne il cursore sul video nuovo
	call	cursor
	
disp4:	pop	hl
	pop	af
	ret

;------------------------------------------------------
; Visualizza l'indirizzo a video
; DE deve contenere la posizione del video vecchio. Il video nuovo deve essere già posizionato
; HL contiene l'indirizzo da visualizzare
;

visadr:	ld	a,h			; separa i nibbles di HL che indicano l'indirizzo
	call	srla4
	call	visad1			; visualizza il 1° byte dell'indirizzo

	ld	a,h
	call	visad1			; visualizza il 2° byte dell'indirizzo

	ld	a,l
	call	srla4
	call	visad1			; visualizza il 3° byte dell'indirizzo

	ld	a,l
	call	visad1			; visualizza il 4° byte dell'indirizzo
	
	ret
	
visad1:	and	0fh
	call	dispca			; visualizza il byte dell'indirizzo a video e sui display

	ret

;------------------------------------------------------
; SRL A per quattro volte
;
srla4:	srl	a
	srl	a
	srl	a
	srl	a
	
	ret
	
;------------------------------------------------------
; Accende il cursore
;

curon:	push	af
	push	hl

	ld	a,0ah			; seleziona il registro R10
	out	(8ch),a
	xor	a			; scrive il valore 00h per accendere il cursore
	out	(8dh),a

	ld	a,81h			; accende il cursore sul video vecchio
	ld	hl,(cursv)		; legge la posizione del cursore del video vecchio
	call	waitv
	ld	(hl),a
	
	xor	a			; indica che i cursori sono accesi
	ld	(curfon),a
	
	pop	hl	
        pop	af
        ret

;------------------------------------------------------
; Spegne il cursore
; Sul video nuovo viene sempre spento, anche se lo era già
;

curoff:	push	af
	push	hl

	ld	a,(curfon)		; se i cursori erano già spenti non fa nulla
	cp	020h
	jr	z,curof1
	
	ld	a,0ah			; seleziona il registro R10
	out	(8ch),a
	
	ld	a,020h			; scrive il valore 32 (20h) per spegnere il cursore
	out	(8dh),a
	
	ld	hl,(cursv)		; spegne il cursore sul video vecchio
	call	waitv
	ld	(hl),a
	
	ld	(curfon),a		; indica che i cursori sono spenti
	
curof1:	pop	hl
	pop	af
        ret

;------------------------------------------------------
; Routine per la gestione dei tasti BREAK

break:	ld	hl,inizio		; salta all'inizio del programma ritornando dall'interrupt non mascherabile
	push	hl
	retn

;------------------------------------------------------
; Azzeramento riga messaggi

clrmsg:	push	de
	push	hl

	ld	hl,(cursn)		; salva le posizioni dei cursori nello stack
	push	hl
	ld	hl,(cursv)
	push	hl

	ld	hl,msg0
	ld	de,0000h
	call	vis
	
	pop	hl			; recupera le posizioni dei cursori
	ld	(cursv),hl
	pop	hl
	ld	(cursn),hl
	
	call	lf060			; riposiziona il cursore sul video nuovo
	
	pop	hl
	pop	de
	
	ret

;------------------------------------------------------
; Inizializzazione schermata video

inivid:
	call	initn			; pulisce il video nuovo
        call	initv			; pulisce il video vecchio

	ld	hl,0000h		; azzera la posizione del cursore
        ld	(cursv),hl
        ld	(cursn),hl

        xor	a			; indica che i cursori sono accesi, in modo da spegnerli nella call curoff
        ld	(curfon),a
        call	curoff			; spegne il cursore
	ret
	
;------------------------------------------------------
; Posiziona in C il display da utilizzare e incrementa la posizione del cursore dei display

posdis:	push	af
	
	ld	a,(cursd)		; recupera la posizione sui display
	ld	c,a			; e la mette in C
	dec	a			; salva la nuova posizione
	ld	(cursd),a
	
	pop	af
	ret
	
;------------------------------------------------------

msg0:	.byte	0Dh, 00h, "                            "	; Utilizzato per azzerare una riga a video (o l'area messaggi)
	.byte	"    ", 00h
msg1:	.byte	00h, 00h, "--- TEST RAM ---", 00h
msg2:	.byte	02h, 00h, "RAM DA TESTARE:" ,00h
msg3:	.byte	03h, 00h, "INDIRIZZO INIZIALE (ESAD.): ", 00h
msg4:	.byte	04h, 00h, "INDIRIZZO FINALE (ESAD.)  : ", 00h
msg5:	.byte	06h, 00h, "RAM CHE NON SI DEVE "
	.byte	"MODIFICARE:", 00h
msg6:	.byte	07h, 00h, "INDIRIZZO INIZIALE (ESAD.): ", 00h
msg7:	.byte	08h, 00h, "INDIRIZZO FINALE (ESAD.)  : ", 00h
msg8:	.byte	0Ah, 00h, "ATTENDERE...", 00h
msg9:	.byte	0Bh, 00h, "*** RAM OK ***", 00h
msg10:	.byte	0Bh, 00h, "*** ERRORE - INDIRIZZO: ", 00h
msg11:	.byte	0Bh, 00h, "*** ERRORE ***", 01h
	.byte	0Ch, 00h, "BYTE CAMBIATO - INDIRIZZO: ", 00h
msg12:	.byte	0Eh, 00h, "--- FINE PROGRAMMA ---", 01h	
	.byte	0Fh, 00h, "PREMERE BREAK PER RIPETERE", 00h
msg13:	.byte	0Dh, 00h, "ERRORE: INDIRIZZO < 0100", 00h
msg14:	.byte	0Dh, 00h, "ERR: INDIRIZZO INIZIALE<="
	.byte	"FINALE", 00h
msg15:	.byte	00h, 00h, "--- TEST RAM SEMPLICE ---", 00h
msg16:	.byte	00h, 00h, "--- TEST RAM AVANZATO ---", 00h
	
adr1:	.byte	0Ah, 0Dh					; posizione (riga/colonna) a video dell'indirizzo in fase di test

menu:	.byte	02h, 00h, "TIPO DI TEST:", 01h
	.byte	03h, 00h, "1 - SEMPLICE", 01h
	.byte	04h, 00h, "2 - AVANZATO", 01h
	.byte	05h, 00h, "3 - FINE PROGRAMMA", 01h
	.byte	07h, 00h, "SCEGLI: ", 00h

help:	.byte	09h, 00h, "1-VIENE CONTROLLATA "
	.byte	"SOLO", 01h
	.byte	0Ah, 00h, "  LA RAM PER 00, FF, 55, AA", 01h
	.byte	0Bh, 00h, "2-PER OGNI INDIRIZZO "
	.byte	"CONTROLLATO", 01h
	.byte	0Ch, 00h, "  SI VERIFICA CHE LE ALTRE "
	.byte	"CELLE", 01h
	.byte	0Dh, 00h, "  DI RAM INSTALLATA NON "
	.byte	"VENGANO", 01h
	.byte	0Eh, 00h, "  MODIFICATE", 00h

disper:	.byte	086h, 0afh, 02fh, 0ffh, 08ch, 088h, 042h, 0c0h	; Err. Pag.0

errpag:	.byte	"ERRORE RAM IN PAGINA 0", 00h

tabds1:	.byte	08h, 092h, 046h, 0FFh, 0F9h, 0BFh, 0A4h, 0BFh, 0B0h	; SC. 1-2-3
tabds2:	.byte	04h, 0AFh, 007h, 0F9h, 02bh				; RT.IN.
tabds3:	.byte	04h, 0AFh, 007h, 08Eh, 079h				; RT.FI.
tabds4:	.byte	04h, 0AFh, 048h, 0F9h, 02bh				; RM.IN.
tabds5:	.byte	04h, 0AFh, 048h, 08Eh, 079h				; RM.FI.
tabds6: .byte	03h, 088h, 087h, 007h					; ATT.
tabds7:	.byte	03h, 086h, 0AFh, 02Fh					; ERR.
tabds8:	.byte	03h, 086h, 0AFh, 048h					; ERM.
tabds9:	.byte	06h, 0AFh, 088h, 0C8h, 0FFh, 0C0h, 0B6h			; RAM OK

;------------------------------------------------------

	.org	0f7ffh
	.byte	00h
	
	.end